DOS批處理編程的高級(jí)技巧有哪些-創(chuàng)新互聯(lián)

DOS批處理編程的高級(jí)技巧有哪些，相信很多沒(méi)有經(jīng)驗(yàn)的人對(duì)此束手無(wú)策，為此本文總結(jié)了問(wèn)題出現(xiàn)的原因和解決方法，通過(guò)這篇文章希望你能解決這個(gè)問(wèn)題。

創(chuàng)新互聯(lián)建站服務(wù)項(xiàng)目包括武山網(wǎng)站建設(shè)、武山網(wǎng)站制作、武山網(wǎng)頁(yè)制作以及武山網(wǎng)絡(luò)營(yíng)銷(xiāo)策劃等。多年來(lái)，我們專(zhuān)注于互聯(lián)網(wǎng)行業(yè)，利用自身積累的技術(shù)優(yōu)勢(shì)、行業(yè)經(jīng)驗(yàn)、深度合作伙伴關(guān)系等，向廣大中小型企業(yè)、政府機(jī)構(gòu)等提供互聯(lián)網(wǎng)行業(yè)的解決方案，武山網(wǎng)站推廣取得了明顯的社會(huì)效益與經(jīng)濟(jì)效益。目前，我們服務(wù)的客戶(hù)以成都為中心已經(jīng)輻射到武山省份的部分城市，未來(lái)相信會(huì)繼續(xù)擴(kuò)大服務(wù)區(qū)域并繼續(xù)獲得客戶(hù)的支持與信任！

一、交互界面設(shè)計(jì)

沒(méi)啥說(shuō)的，看看高手設(shè)計(jì)的菜單界面吧：

@echo off
cls
title 終極多功能修復(fù)
:menu
cls
color 0A
echo.
echo         ==============================
echo         請(qǐng)選擇要進(jìn)行的操作，然后按回車(chē)
echo         ==============================
echo.
echo       1.網(wǎng)絡(luò)修復(fù)及上網(wǎng)相關(guān)設(shè)置,修復(fù)IE,自定義屏蔽網(wǎng)站
echo.
echo       2.病毒專(zhuān)殺工具，端口關(guān)閉工具,關(guān)閉自動(dòng)播放
echo.
echo       3.清除所有多余的自啟動(dòng)項(xiàng)目，修復(fù)系統(tǒng)錯(cuò)誤
echo.
echo       4.清理系統(tǒng)垃圾,提高啟動(dòng)速度
echo.
echo       Q.退出
echo.
echo.
:cho
set choice=
set /p choice=     請(qǐng)選擇:
IF NOT "%choice%"=="" SET choice=%choice:~0,1%
if /i "%choice%"=="1" goto ip
if /i "%choice%"=="2" goto setsave
if /i "%choice%"=="3" goto kaiji
if /i "%choice%"=="4" goto clean
if /i "%choice%"=="Q" goto endd
echo 選擇無(wú)效，請(qǐng)重新輸入
echo.
goto cho

只要學(xué)完本教程前面的章節(jié)，上面的程序應(yīng)該能看懂了。

二、if…else…條件語(yǔ)句

前面已經(jīng)談到，DOS條件語(yǔ)句主要有以下形式
IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command
增強(qiáng)用法：IF [/I] string1 compare-op string2 command
增強(qiáng)用法中加上/I就不區(qū)分大小寫(xiě)了!
增強(qiáng)用法中還有一些用來(lái)判斷數(shù)字的符號(hào)：

EQU - 等于
NEQ - 不等于
LSS - 小于
LEQ - 小于或等于
GTR - 大于
GEQ - 大于或等于

上面的command命令都可以用小括號(hào)來(lái)使用多條命令的組合，包括else子句，組合命令中可以嵌套使用條件或循環(huán)命令。

例如:

    IF EXIST filename (
        del filename
    ) ELSE (
        echo filename missing
    )

也可寫(xiě)成：
if exist filename (del filename) else (echo filename missing)

但這種寫(xiě)法不適合命令太多或嵌套命令的使用。

三、循環(huán)語(yǔ)句

1、指定次數(shù)循環(huán)

FOR /L %variable IN (start,step,end) DO command [command-parameters]

組合命令：
FOR /L %variable IN (start,step,end) DO (
Command1
Command2
……
)

2、對(duì)某集合執(zhí)行循環(huán)語(yǔ)句。

FOR %%variable IN (set) DO command [command-parameters]

  %%variable  指定一個(gè)單一字母可替換的參數(shù)。
  (set)      指定一個(gè)或一組文件?？梢允褂猛ㄅ浞?。
  command   對(duì)每個(gè)文件執(zhí)行的命令，可用小括號(hào)使用多條命令組合。

FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]

    檢查以 [drive:]path 為根的目錄樹(shù)，指向每個(gè)目錄中的
    FOR 語(yǔ)句。如果在 /R 后沒(méi)有指定目錄，則使用當(dāng)前
目錄。如果集僅為一個(gè)單點(diǎn)(.)字符，則枚舉該目錄樹(shù)。

同前面一樣，command可以用括號(hào)來(lái)組合：
FOR /R [[drive:]path] %variable IN (set) DO (
Command1
Command2
……
commandn
)

3、條件循環(huán)

    上面的循環(huán)結(jié)構(gòu)是用for命令來(lái)實(shí)現(xiàn)的，for命令循環(huán)有一個(gè)缺點(diǎn)，就是整個(gè)循環(huán)被當(dāng)作一條命令語(yǔ)句，涉及到變量延遲的問(wèn)題。
    利用goto語(yǔ)句和條件判斷，dos可以實(shí)現(xiàn)條件循環(huán)，很簡(jiǎn)單啦，看例子：

例：

@echo off
set var=0
rem ************循環(huán)開(kāi)始了
:continue
set /a var+=1
echo 第%var%次循環(huán)
if %var% lss 100 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause

例：

@echo off
set var=100
rem ************循環(huán)開(kāi)始了
:continue
echo 第%var%次循環(huán)
set /a var-=1
if %var% gtr 0 goto continue
rem ************循環(huán)結(jié)束了
echo 循環(huán)執(zhí)行完畢
pause

四、子程序

在批處理程序中可以調(diào)用外部可運(yùn)行程序，比如exe程序，也可調(diào)用其他批處理程序，這些也可以看作子程序，但是不夠方便，如果被調(diào)用的程序很多，就顯得不夠簡(jiǎn)明了，很繁瑣。

在windowsXP中，批處理可以調(diào)用本程序中的一個(gè)程序段，相當(dāng)于子程序，這些子程序一般放在主程序后面。

子程序調(diào)用格式：

CALL :label arguments

子程序語(yǔ)法：
:label
command1
command2
......
commandn
goto :eof

在子程序段中，參數(shù)%0指標(biāo)簽:label

子過(guò)程一般放在最后，并且注意在主程序最后要加上exit或跳轉(zhuǎn)語(yǔ)句，避免錯(cuò)誤的進(jìn)入子過(guò)程。

子程序和主程序中的變量都是全局變量，其作用范圍都是整個(gè)批處理程序。

傳至子程序的參數(shù)在call語(yǔ)句中指定，在子程序中用%1、%2至%9的形式調(diào)用，而子程序返回主程序的數(shù)據(jù)只需在調(diào)用結(jié)束后直接引用就可以了，當(dāng)然也可以指定返回變量，請(qǐng)看下面的例子。

子程序例1：

@echo off
call :sub return 你好
echo 子程序返回值：%return%
pause

:sub
set %1=%2
goto :eof

運(yùn)行結(jié)果：你好

子程序例2：設(shè)計(jì)一個(gè)求多個(gè)整數(shù)相加的子程序

@echo off
set sum=0
call :sub sum 10 20 35
echo 數(shù)據(jù)求和結(jié)果：%sum%
pause

:sub
rem 參數(shù)1為返回變量名稱(chēng)
set /a %1=%1+%2
shift /2
if not "%2"=="" goto sub
goto :eof

運(yùn)行結(jié)果：65

在win98系統(tǒng)中，不支持上面這種標(biāo)號(hào)調(diào)用，須將子程序單獨(dú)保存為一個(gè)批處理程序，然后調(diào)用。


五、用ftp命令實(shí)現(xiàn)自動(dòng)下載

ftp是常用的下載工具，ftp界面中有40多個(gè)常用命令，自己學(xué)習(xí)了，不介紹了。這里介紹如何用dos命令行調(diào)用ftp命令，實(shí)現(xiàn)ftp自動(dòng)登錄，并上傳下載，并自動(dòng)退出ftp程序。

其實(shí)可以將ftp命令組合保存為一個(gè)文本文件，然后用以下命令調(diào)用即可。

ftp -n -s:[[drive:]path]filename

上面的filename為ftp命令文件，包括登錄IP地址，用戶(hù)名、密碼、操作命令等
例：


open 90.52.8.3 ＃打開(kāi)ip
user iware ＃用戶(hù)為iware
password8848 ＃密碼
bin ＃二進(jìn)制傳輸模式
prompt
cd tmp1 ＃切換至iware用戶(hù)下的tmp1目錄
pwd
lcd d:\download ＃本地目錄
mget * ＃下載tmp1目錄下的所有文件
bye ＃退出ftp


六、用7-ZIP實(shí)現(xiàn)命令行壓縮和解壓功能

語(yǔ)法格式：（詳細(xì)情況見(jiàn)7-zip幫助文件，看得頭暈可以跳過(guò)，用到再學(xué)）

7z <command> [<switch>...] <base_archive_name> [<arguments>...]

7z.exe的每個(gè)命令都有不同的參數(shù)<switch>,請(qǐng)看幫助文件
<base_archive_name>為壓縮包名稱(chēng)
<arguments>為文件名稱(chēng)，支持通配符或文件列表

其中，7z是至命令行壓縮解壓程序7z.exe，<command>是7z.exe包含的命令，列舉如下：

a： Adds files to archive. 添加至壓縮包
a命令可用參數(shù)：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-sfx (create SFX)
-si (use StdIn)
-so (use StdOut)
-ssw (Compress shared files)
-t (Type of archive)
-u (Update)
-v (Volumes)
-w (Working Dir)
-x (Exclude)

b： Benchmark

d： Deletes files from archive. 從壓縮包中刪除文件
d命令可用參數(shù)：
-i (Include)
-m (Method)
-p (Set Password)
-r (Recurse)
-u (Update)
-w (Working Dir)
-x (Exclude)

e： Extract解壓文件至當(dāng)前目錄或指定目錄
e命令可用參數(shù)：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

l： Lists contents of archive.
t： Test
u： Update

x： eXtract with full paths用文件的完整路徑解壓至當(dāng)前目錄或指定目錄
x命令可用參數(shù)：
-ai (Include archives)
-an (Disable parsing of archive_name)
-ao (Overwrite mode)
-ax (Exclude archives)
-i (Include)
-o (Set Output Directory)
-p (Set Password)
-r (Recurse)
-so (use StdOut)
-x (Exclude)
-y (Assume Yes on all queries)

七、調(diào)用VBScript程序

使用 Windows 腳本宿主，可以在命令提示符下運(yùn)行腳本。CScript.exe 提供了用于設(shè)置腳本屬性的命令行開(kāi)關(guān)。

用法：CScript 腳本名稱(chēng) [腳本選項(xiàng)...] [腳本參數(shù)...]

選項(xiàng)：
//B 批模式：不顯示腳本錯(cuò)誤及提示信息
//D 啟用 Active Debugging
//E:engine 使用執(zhí)行腳本的引擎
//H:CScript 將默認(rèn)的腳本宿主改為 CScript.exe
//H:WScript 將默認(rèn)的腳本宿主改為 WScript.exe （默認(rèn)）
//I 交互模式（默認(rèn)，與 //B 相對(duì))
//Job:xxxx 執(zhí)行一個(gè) WSF 工作
//Logo 顯示徽標(biāo)（默認(rèn)）
//Nologo 不顯示徽標(biāo)：執(zhí)行時(shí)不顯示標(biāo)志
//S 為該用戶(hù)保存當(dāng)前命令行選項(xiàng)
//T:nn 超時(shí)設(shè)定秒：允許腳本運(yùn)行的最長(zhǎng)時(shí)間
//X 在調(diào)試器中執(zhí)行腳本
//U 用 Unicode 表示來(lái)自控制臺(tái)的重定向 I/O

“腳本名稱(chēng)”是帶有擴(kuò)展名和必需的路徑信息的腳本文件名稱(chēng)，如d:\admin\vbscripts\chart.vbs。
“腳本選項(xiàng)和參數(shù)”將傳遞給腳本。腳本參數(shù)前面有一個(gè)斜杠 (/)。每個(gè)參數(shù)都是可選的；但不能在未指定腳本名稱(chēng)的情況下指定腳本選項(xiàng)。如果未指定參數(shù)，則 CScript 將顯示 CScript 語(yǔ)法和有效的宿主參數(shù)。

八、將批處理轉(zhuǎn)化為可執(zhí)行文件：

由于批處理文件是一種文本文件，任何人都可以對(duì)其進(jìn)行隨便編輯，不小心就會(huì)把里面的命令破壞掉，所以如果將其轉(zhuǎn)換成.com格式的可執(zhí)行文件，不僅執(zhí)行效率會(huì)大大提高，而且不會(huì)破壞原來(lái)的功能，更能將優(yōu)先級(jí)提到高。Bat2Com就可以完成這個(gè)轉(zhuǎn)換工作。

小知識(shí)：在DOS環(huán)境下，可執(zhí)行文件的優(yōu)先級(jí)由高到低依次為.com>.exe>.bat>.cmd，即如果在同一目錄下存在文件名相 同的這四類(lèi)文件，當(dāng)只鍵入文件名時(shí)，DOS執(zhí)行的是name.com，如果需要執(zhí)行其他三個(gè)文件，則必須指定文件的全名，如name.bat。

這是一個(gè)只有5.43K大小的免費(fèi)綠色工具，可以運(yùn)行在純DOS或DOS窗口的命令行中，用法：Bat2Com FileName，這樣就會(huì)在同一目錄下生成一個(gè)名為FileNme.com的可執(zhí)行文件，執(zhí)行的效果和原來(lái)的.bat文件一樣。

九、時(shí)間延遲

什么是時(shí)間延遲？顧名思義，就是執(zhí)行一條命令后延遲一段時(shí)間再進(jìn)行下一條命令。

延遲的應(yīng)用見(jiàn)下節(jié)：“模擬進(jìn)度條”。

1、利用ping命令延時(shí)
例：

@echo off
echo 延時(shí)前：%time%
ping /n 3 127.0.0.1 >nul
echo 延時(shí)后：%time%
pause

解說(shuō)：用到了ping命令的“/n”參數(shù)，表示要發(fā)送多少次請(qǐng)求到指定的ip。本例中要發(fā)送3次請(qǐng)求到本機(jī)的ip（127.0.0.1）。127.0.0.1可簡(jiǎn)寫(xiě)為127.1?！?gt;nul”就是屏蔽掉ping命令所顯示的內(nèi)容。

2、利用for命令延時(shí)
例：

@echo off
echo 延時(shí)前：%time%
for /l %%i in (1,1,5000) do echo %%i>nul
echo 延時(shí)后：%time%
pause

解說(shuō)：原理很簡(jiǎn)單，就是利用一個(gè)計(jì)次循環(huán)并屏蔽它所顯示的內(nèi)容來(lái)達(dá)到延時(shí)的目的。

3、利用vbs延遲函數(shù)，精確度毫秒，誤差1000毫秒內(nèi)

例：

@echo off
echo %time%
call :delay 5000
echo %time%
pause
exit

:delay
echo WScript.Sleep %1>delay.vbs
CScript //B delay.vbs
del delay.vbs
goto :eof

運(yùn)行顯示：
10:44:06.45
10:44:11.95
請(qǐng)按任意鍵繼續(xù). . .

上面的運(yùn)行結(jié)果顯示實(shí)際延時(shí)了5500毫秒，多出來(lái)的500毫秒時(shí)建立和刪除臨時(shí)文件所耗費(fèi)的時(shí)間。誤差在一秒之內(nèi)。

4、僅用批處理命令實(shí)現(xiàn)任意時(shí)間延遲，精確度10毫秒，誤差50毫秒內(nèi)

僅用批處理命令就可以實(shí)現(xiàn)延遲操作。

例：

@echo off
set /p delay=請(qǐng)輸入需延遲的毫秒數(shù)：
set TotalTime=0
set NowTime=%time%
::讀取起始時(shí)間，時(shí)間格式為：13:01:05.95
echo 程序開(kāi)始時(shí)間：%NowTime%
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
::讀取起始時(shí)間的分鐘數(shù)
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將起始時(shí)間的秒數(shù)轉(zhuǎn)為毫秒
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
:: 讀取現(xiàn)在時(shí)間的分鐘數(shù)
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
::將現(xiàn)在時(shí)間的秒數(shù)轉(zhuǎn)為毫秒
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %delay% goto delay_continue
echo 程序結(jié)束時(shí)間：%time%
echo 設(shè)定延遲時(shí)間：%delay%毫秒
echo 實(shí)際延遲時(shí)間：%TotalTime%毫秒
pause

運(yùn)行顯示：

請(qǐng)輸入需延遲的毫秒數(shù)：6000
程序開(kāi)始時(shí)間：15:32:16.37
程序結(jié)束時(shí)間：15:32:22.37
設(shè)定延遲時(shí)間：6000毫秒
實(shí)際延遲時(shí)間：6000毫秒
請(qǐng)按任意鍵繼續(xù). . .

實(shí)現(xiàn)原理：首先設(shè)定要延遲的毫秒數(shù)，然后用循環(huán)累加時(shí)間，直到累加時(shí)間大于等于延遲時(shí)間。

誤差：windows系統(tǒng)時(shí)間只能精確到10毫秒，所以理論上有可能存在10毫秒誤差。
經(jīng)測(cè)試，當(dāng)延遲時(shí)間大于500毫秒時(shí)，上面的延遲程序一般不存在誤差。當(dāng)延遲時(shí)間小于500毫秒時(shí)，可能有幾十毫秒誤差，為什么？因?yàn)檠舆t程序本身也是有運(yùn)行時(shí)間的，同時(shí)系統(tǒng)時(shí)間只能精確到10毫秒。

為了方便引用，可將上面的例子改為子程序調(diào)用形式：

@echo off
echo 程序開(kāi)始時(shí)間：%Time%
call :delay 10
echo 實(shí)際延遲時(shí)間：%totaltime%毫秒
echo 程序結(jié)束時(shí)間：%time%
pause
exit

::-----------以下為延時(shí)子程序--------------------
:delay
@echo off
if "%1"=="" goto :eof
set DelayTime=%1
set TotalTime=0
set NowTime=%time%
::讀取起始時(shí)間，時(shí)間格式為：13:01:05.95
:delay_continue
set /a minute1=1%NowTime:~3,2%-100
set /a second1=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set NowTime=%time%
set /a minute2=1%NowTime:~3,2%-100
set /a second2=1%NowTime:~-5,2%%NowTime:~-2%0-100000
set /a TotalTime+=(%minute2%-%minute1%+60)%%60*60000+%second2%-%second1%
if %TotalTime% lss %DelayTime% goto delay_continue
goto :eof

十、模擬進(jìn)度條

下面給出一個(gè)模擬進(jìn)度條的程序。如果將它運(yùn)用在你自己的程序中，可以使你的程序更漂亮。

@echo off
mode con cols=113 lines=15 &color 9f
cls
echo.
echo 程序正在初始化. . . 
echo.
echo ┌──────────────────────────────────────┐
set/p= ■<nul
for /L %%i in (1 1 38) do set /p a=■<nul&ping /n 1 127.0.0.1>nul
echo  100%%
echo └──────────────────────────────────────┘
pause

解說(shuō)：“set /p a=■<nul”的意思是：只顯示提示信息“■”且不換行，也不需手工輸入任何信息，這樣可以使每個(gè)“■”在同一行逐個(gè)輸出。“ping /n 0 127.1>nul”是輸出每個(gè)“■”的時(shí)間間隔，即每隔多少時(shí)間輸出一個(gè)“■”。

十一、特殊字符的輸入及應(yīng)用

開(kāi)始 -> 運(yùn)行 -> 輸入cmd -> edit -> ctrl+p（意思是允許輸入特殊字符）-> 按ctrl+a將會(huì)顯示笑臉圖案。

（如果要繼續(xù)輸入特殊字符請(qǐng)?jiān)俅伟碿trl+p，然后ctrl+某個(gè)字母）

以上是特殊字符的輸入方法，選自[英雄]教程，很管用的。也就是用編輯程序edit輸入特殊字符，然后保存為一文本文件，再在windows下打開(kāi)此文件，復(fù)制其中的特殊符號(hào)即可。

一些簡(jiǎn)單的特殊符號(hào)可以在dos命令窗口直接輸入，并用重定向保存為文本文件。
例：

C:>ECHO ^G>temp.txt
“^G”是用Ctrl＋G或Alt＋007輸入，輸入多個(gè)^G可以產(chǎn)生多聲?shū)Q響。

特殊字符的應(yīng)用也很有意思，這里僅舉一例：退格鍵

退格鍵表示刪除左邊的字符，此鍵不能在文檔中正常輸入，但可以通過(guò)edit編輯程序錄入并復(fù)制出來(lái)。即“”。

利用退格鍵，可以設(shè)計(jì)閃爍文字效果

例：文字閃爍

@echo off
:start
set/p=床前明月光<nul
::顯示文字，光標(biāo)停于行尾
ping -n 0 127.0.0.1>nul
::設(shè)置延遲時(shí)間
set /p a=<nul
:: 輸出一些退格符將光標(biāo)置于該行的最左端（退格符的數(shù)量可以自己調(diào)整）。
set /p a=                <nul
::輸出空格將之前輸出的文字覆蓋掉。
set /p a=<nul
::再次輸出退格符將光標(biāo)置于該行的最左端，這里的退格符數(shù)量一定不能比前面的空格數(shù)少。
::否則光標(biāo)不能退到最左端。
goto start

例：輸出唐詩(shī)一首，每行閃動(dòng)多次

代碼如下:


@echo off
setlocal enabledelayedexpansion


set str=床前明月光 疑是地上霜 舉頭望明月 低頭思故鄉(xiāng)

::定義字符串str
for %%i in (%str%) do (
 rem 由于str中含有空格，則以空格為分隔符將str中的每一個(gè)部分依次賦給變量%%i。
    set char=%%i
    echo.
    echo.
    for /l %%j in (0,1,5) do (
        set/p=!char:~%%j,1!<nul
 rem 依次取出變量char中的每一個(gè)字符，并顯示。
        ping -n 0 127.0.0.1>nul
 rem 設(shè)置輸出每個(gè)字符的時(shí)間延遲。
    )
 call :hero %%i
)
pause>nul
exit

:hero
for /l %%k in (1,1,10) do (
 ping /n 0 127.0.0.1>nul
 set /p a=<nul
 set /p a=                <nul
 set /p a=<nul
 ping /n 0 127.0.0.1>nul
 set /p a=%1<nul
)
::文字閃動(dòng)
goto :eof

十二、隨機(jī)數(shù)（%random%）的應(yīng)用技巧

%RANDOM% 系統(tǒng)變量 返回 0 到 32767 之間的任意十進(jìn)制數(shù)字。由 Cmd.exe 生成。

2的15次方等于32768，上面的0～32767實(shí)際就是15位二進(jìn)制數(shù)的范圍。

那么，如何獲取100以?xún)?nèi)的隨機(jī)數(shù)呢？很簡(jiǎn)單，將%RANDOM%按100進(jìn)行求余運(yùn)算即可，見(jiàn)例子。

例：生成5個(gè)100以?xún)?nèi)的隨機(jī)數(shù)

@echo off
setlocal enabledelayedexpansion
for /L %%i in (1 1 5) do (
  set /a randomNum=!random!%%100
  echo 隨機(jī)數(shù)：!randomNum!
)
pause

運(yùn)行結(jié)果：（每次運(yùn)行不一樣）
隨機(jī)數(shù)：91
隨機(jī)數(shù)：67
隨機(jī)數(shù)：58
隨機(jī)數(shù)：26
隨機(jī)數(shù)：20
請(qǐng)按任意鍵繼續(xù). . .

求余數(shù)運(yùn)算set /a randomNum=!random!%%100中的100可以是1～32768之間的任意整數(shù)。

總結(jié)：利用系統(tǒng)變量%random%，求余數(shù)運(yùn)算%%，字符串處理等，可以實(shí)現(xiàn)很多隨機(jī)處理。

思考題目：生成給定位數(shù)的隨機(jī)密碼

解答思路：將26個(gè)英文字母或10數(shù)字以及其它特殊字符組成一個(gè)字符串，隨機(jī)抽取其中的若干字符。

參考答案1：（簡(jiǎn)單）

@echo off
call :randomPassword 5 pass1 pass2
echo %pass1% %pass2% 
pause
exit

:randomPassword
::---------生成隨機(jī)密碼
::---------%1為密碼長(zhǎng)度，%2及以后為返回變量名稱(chēng)
::---------for命令最多只能區(qū)分31個(gè)字段
@echo off
set password_len=%1
if not defined password_len goto :eof
if %password_len% lss 1 goto :eof
set wordset=a b c d e f g h i j k l m n o p q r s t u v w x y z
set return=
set num=0
:randomPassword1
set /a num+=1
set /a numof=%random%%%26+1
for /f "tokens=%numof% delims= " %%i in ("%wordset%") do set return=%return%%%i
if %num% lss %password_len% goto randomPassword1
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

參考答案2：（最優(yōu)

@echo off
call :randomPassword 6 pass1 pass2 pass3
echo %pass1% %pass2% %pass3%
pause
exit

:randomPassword
::---------生成隨機(jī)密碼
::---------%1為密碼長(zhǎng)度，%2及以后為返回變量名稱(chēng)
::---------goto循環(huán)、變量嵌套、命令嵌套
@echo off
if "%1"=="" goto :eof
if %1 lss 1 goto :eof
set password_len=%1
set return=
set wordset=abcdefghijklmnopqrstuvwxyz023456789_
::---------------------------循環(huán)
:randomPassword1
set /a numof=%random%%%36
call set return=%return%%%wordset:~%numof%,1%%
set /a password_len-=1
if %password_len% gtr 0 goto randomPassword1
::---------------------------循環(huán)
if not "%2"=="" set %2=%return%
shift /2
if not "%2"=="" goto randomPassword
goto :eof

說(shuō)明：本例涉及到變量嵌套和命令嵌套的應(yīng)用，見(jiàn)后。


十三、變量嵌套 與 命令嵌套

和其它編程語(yǔ)言相比，dos功能顯得相對(duì)簡(jiǎn)單，要實(shí)現(xiàn)比較復(fù)雜的功能，需要充分運(yùn)用各種技巧，變量嵌套與命令嵌套就是此類(lèi)技巧之一。

先復(fù)習(xí)一下前面的“字符串截取”的關(guān)鍵內(nèi)容：

**********************************************
截取功能統(tǒng)一語(yǔ)法格式為：%a:~[m[,n]]%
**********************************************

方括號(hào)表示可選，%為變量標(biāo)識(shí)符，a為變量名，不可少，冒號(hào)用于分隔變量名和說(shuō)明部分，符號(hào)～可以簡(jiǎn)單理解為“偏移”即可，m為偏移量（缺省為0），n為截取長(zhǎng)度（缺省為全部）。

百分號(hào)如果需要當(dāng)成單一字符，必須寫(xiě)成%%

以上是dos變量處理的通用格式，如果其中的m、n為變量，那么這種情況就是變量嵌套了。

比如設(shè)變量word為“abcdefghij”，變量num為“123456789”
%word:~4,1%為e，其中4可以從變量num中取值，即%num:~3,1%，寫(xiě)成組合形式如下：
%word:~%num:~3,1%,1% 經(jīng)測(cè)試這種寫(xiě)法不能正確執(zhí)行，寫(xiě)成%word:~(%num:~3,1%),1%同樣不行，那么，怎么實(shí)現(xiàn)這種變量嵌套呢？這就必須結(jié)合命令嵌套。

什么是命令嵌套呢？簡(jiǎn)單的說(shuō)，首先用一條dos命令生成一個(gè)字符串，而這個(gè)字符串是另一條dos命令，用call語(yǔ)句調(diào)用字符串將其執(zhí)行，從而得到最終結(jié)果。

例：用call語(yǔ)句實(shí)現(xiàn)命令嵌套

@echo off
set str1=aaa echo ok bbb
echo 初始字符串：%str1%
echo 生成命令字符串如下：
echo %str1:~4,7%
echo 運(yùn)行命令字符串生成最終結(jié)果為：
call %str1:~4,7%
pause

運(yùn)行顯示：
初始字符串：aaa echo ok bbb
生成命令字符串如下：
echo ok
運(yùn)行命令字符串生成最終結(jié)果為：
ok
請(qǐng)按任意鍵繼續(xù). . .

看完上述內(nèi)容，你們掌握DOS批處理編程的高級(jí)技巧有哪些的方法了嗎？如果還想學(xué)到更多技能或想了解更多相關(guān)內(nèi)容，歡迎關(guān)注創(chuàng)新互聯(lián)行業(yè)資訊頻道，感謝各位的閱讀！

網(wǎng)頁(yè)名稱(chēng)：DOS批處理編程的高級(jí)技巧有哪些-創(chuàng)新互聯(lián)
標(biāo)題來(lái)源：http://bm7419.com/article28/cesscp.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供網(wǎng)站制作、商城網(wǎng)站、全網(wǎng)營(yíng)銷(xiāo)推廣、企業(yè)網(wǎng)站制作、品牌網(wǎng)站制作、ChatGPT

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶(hù)投稿、用戶(hù)轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話(huà)：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來(lái)源： 創(chuàng)新互聯(lián)

成都做網(wǎng)站